source: code/branches/buildsystem/cmake/FindOggVorbis.cmake @ 2103

# - Try to find ogg/vorbis
# Once done this will define
#
#  OGG_FOUND - system has ogg
#  OGG_INCLUDE_DIR
#  OGG_LIBRARY
#  VORBIS_FOUND - system has vorbis
#  VORBIS_INCLUDE_DIR
#  VORBIS_LIBRARY
#  VORBISENC_LIBRARY
#  VORBISFILE_LIBRARY
#
# $OGGVORBISDIR is an environment variable used for finding ogg/vorbis.
#
# Several changes and additions by Fabian 'x3n' Landau
# Most of all rewritten by Adrian Friedli
#                 > www.orxonox.net <

SET(OGG_SEARCH_PATHS
  $ENV{OGGVORBISDIR}
  /usr/local
  /usr
  /sw
  /opt/local
  /opt/csw
  /opt
)

FIND_PATH(OGG_INCLUDE_DIR ogg/ogg.h
  PATHS ${OGG_SEARCH_PATHS}
  PATH_SUFFIXES include
)

FIND_PATH(VORBIS_INCLUDE_DIR vorbis/codec.h
  PATHS ${OGG_SEARCH_PATHS}
  PATH_SUFFIXES include
)

FIND_LIBRARY(OGG_LIBRARY NAMES ogg
  PATHS ${OGG_SEARCH_PATHS}
  PATH_SUFFIXES lib
)

FIND_LIBRARY(VORBIS_LIBRARY NAMES vorbis
  PATHS ${OGG_SEARCH_PATHS}
  PATH_SUFFIXES lib
)

#FIND_LIBRARY(VORBISENC_LIBRARY NAMES vorbisenc
#  PATHS ${OGG_SEARCH_PATHS}
#  PATH_SUFFIXES lib
#)

FIND_LIBRARY(VORBISFILE_LIBRARY NAMES vorbisfile
  PATHS ${OGG_SEARCH_PATHS}
  PATH_SUFFIXES lib
)

# handle the QUIETLY and REQUIRED arguments and set *_FOUND to TRUE if
# all listed variables are TRUE
INCLUDE(FindPackageHandleStandardArgs)
FIND_PACKAGE_HANDLE_STANDARD_ARGS(OGG DEFAULT_MSG OGG_LIBRARY OGG_INCLUDE_DIR)
FIND_PACKAGE_HANDLE_STANDARD_ARGS(VORBIS DEFAULT_MSG
  VORBIS_LIBRARY
  VORBISFILE_LIBRARY
  #VORBISENC_LIBRARY
  VORBIS_INCLUDE_DIR
)

MARK_AS_ADVANCED(
  OGG_LIBRARY
  OGG_INCLUDE_DIR
  VORBIS_LIBRARY
  VORBISFILE_LIBRARY
  VORBIS_INCLUDE_DIR
)