| 1 | # |
|---|
| 2 | # ORXONOX - the hottest 3D action shooter ever to exist |
|---|
| 3 | # > www.orxonox.net < |
|---|
| 4 | # |
|---|
| 5 | # This program is free software; you can redistribute it and/or |
|---|
| 6 | # modify it under the terms of the GNU General Public License |
|---|
| 7 | # as published by the Free Software Foundation; either version 2 |
|---|
| 8 | # of the License, or (at your option) any later version. |
|---|
| 9 | # |
|---|
| 10 | # This program is distributed in the hope that it will be useful, |
|---|
| 11 | # but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 12 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
|---|
| 13 | # GNU General Public License for more details. |
|---|
| 14 | # |
|---|
| 15 | # You should have received a copy of the GNU General Public License along |
|---|
| 16 | # with this program; if not, write to the Free Software Foundation, |
|---|
| 17 | # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA. |
|---|
| 18 | # |
|---|
| 19 | # |
|---|
| 20 | # Author: |
|---|
| 21 | # Reto Grieder |
|---|
| 22 | # Description: |
|---|
| 23 | # Adds a library or an executable like ADD_LIBRARY/ADD_EXECUTABLE, but |
|---|
| 24 | # accepts a lot more input information. Simply supply the keywords |
|---|
| 25 | # described below in any order you wish. |
|---|
| 26 | # The output is then stored in "_arg_ARGNAME" where ARGNAME is the the |
|---|
| 27 | # name of the switch or list. |
|---|
| 28 | # |
|---|
| 29 | # Switches: (when given --> TRUE, FALSE otherwise) |
|---|
| 30 | # FIND_HEADER_FILES: Searches the current directory for all header files |
|---|
| 31 | # and adds them to the target. |
|---|
| 32 | # EXCLUDE_FROM_ALL: Inherited from ADD_LIBRARY/ADD_EXECUTABLE |
|---|
| 33 | # ORXONOX_EXTERNAL: Specify this for third party libraries |
|---|
| 34 | # NO_DLL_INTERFACE: Link statically with MSVC |
|---|
| 35 | # NO_SOURCE_GROUPS: Don't create msvc source groups |
|---|
| 36 | # MODULE: For dynamic module libraries (libraries only) |
|---|
| 37 | # PLUGIN: For dynamic plugin libraries (libraries only) |
|---|
| 38 | # Plugins are a special kind of modules that can be |
|---|
| 39 | # loaded and unloaded during runtime on demand |
|---|
| 40 | # WIN32: Inherited from ADD_EXECUTABLE (executables only) |
|---|
| 41 | # PCH_NO_DEFAULT: Do not make precompiled header files default if |
|---|
| 42 | # specified with PCH_FILE |
|---|
| 43 | # NO_INSTALL: Do not install the target at all |
|---|
| 44 | # NO_VERSION: Prevents adding any version to a target |
|---|
| 45 | # NO_BUILD_UNITS: Disables automatic (full) build units |
|---|
| 46 | # |
|---|
| 47 | # Lists: |
|---|
| 48 | # LINK_LIBRARIES: Redirects to TARGET_LINK_LIBRARIES |
|---|
| 49 | # LINK_LIBS_LINUX: Redirects to TARGET_LINK_LIBRARIES only on Linux |
|---|
| 50 | # LINK_LIBS_WIN32: Redirects to TARGET_LINK_LIBRARIES only on Windows |
|---|
| 51 | # LINK_LIBS_APPLE: Redirects to TARGET_LINK_LIBRARIES only on Apple |
|---|
| 52 | # LINK_LIBS_UNIX: Redirects to TARGET_LINK_LIBRARIES only on UNIX |
|---|
| 53 | # VERSION: Set version to the binary |
|---|
| 54 | # SOURCE_FILES: Source files for the target |
|---|
| 55 | # DEFINE_SYMBOL: Sets the DEFINE_SYMBOL target property |
|---|
| 56 | # TOLUA_FILES: Files with tolua interface |
|---|
| 57 | # PCH_FILE: Precompiled header file |
|---|
| 58 | # PCH_EXCLUDE: Source files to be excluded from PCH support |
|---|
| 59 | # OUTPUT_NAME: If you want a different name than the target name |
|---|
| 60 | # EXCLUDE_FROM_BUILD_UNITS: Specifies files that are not put into |
|---|
| 61 | # automatic (full) build units. They can still |
|---|
| 62 | # explicitely be included in a BUILD_UNIT (partial) |
|---|
| 63 | # Note: |
|---|
| 64 | # This function also installs the target! |
|---|
| 65 | # Prerequisistes: |
|---|
| 66 | # ORXONOX_DEFAULT_LINK |
|---|
| 67 | # Parameters: |
|---|
| 68 | # _target_name, ARGN for the macro arguments |
|---|
| 69 | # |
|---|
| 70 | |
|---|
| 71 | INCLUDE(BuildUnits) |
|---|
| 72 | INCLUDE(CMakeDependentOption) |
|---|
| 73 | INCLUDE(CapitaliseName) |
|---|
| 74 | INCLUDE(GenerateToluaBindings) |
|---|
| 75 | INCLUDE(ParseMacroArguments) |
|---|
| 76 | INCLUDE(SourceFileUtilities) |
|---|
| 77 | IF(PCH_COMPILER_SUPPORT) |
|---|
| 78 | INCLUDE(PrecompiledHeaderFiles) |
|---|
| 79 | ENDIF() |
|---|
| 80 | |
|---|
| 81 | MACRO(ORXONOX_ADD_LIBRARY _target_name) |
|---|
| 82 | SET(_additional_switches MODULE PLUGIN) |
|---|
| 83 | TU_ADD_TARGET(${_target_name} LIBRARY "${_additional_switches}" ${ARGN}) |
|---|
| 84 | ENDMACRO(ORXONOX_ADD_LIBRARY) |
|---|
| 85 | |
|---|
| 86 | MACRO(ORXONOX_ADD_EXECUTABLE _target_name) |
|---|
| 87 | SET(_additional_switches WIN32) |
|---|
| 88 | TU_ADD_TARGET(${_target_name} EXECUTABLE "${_additional_switches}" ${ARGN}) |
|---|
| 89 | |
|---|
| 90 | # When using Visual Studio we want to use the output directory as working |
|---|
| 91 | # directory and we also want to specify where the external dlls |
|---|
| 92 | # (lua, ogre, etc.) are. The problem hereby is that these information cannot |
|---|
| 93 | # be specified in CMake because they are not stored in the actual project file. |
|---|
| 94 | # This workaround will create a configured *.vcproj.user file that holds the |
|---|
| 95 | # right values. When starting the solution for the first time, |
|---|
| 96 | # these get written to the *vcproj.yourPCname.yourname.user |
|---|
| 97 | IF(MSVC) |
|---|
| 98 | IF(CMAKE_CL_64) |
|---|
| 99 | SET(MSVC_PLATFORM "x64") |
|---|
| 100 | ELSE() |
|---|
| 101 | SET(MSVC_PLATFORM "Win32") |
|---|
| 102 | ENDIF() |
|---|
| 103 | IF(NOT (MSVC_VERSION LESS 1600)) #For all versions >= Visual Studio 2010 |
|---|
| 104 | CONFIGURE_FILE("${CMAKE_SOURCE_DIR}/src/template.vcxproj.user.in" "${CMAKE_CURRENT_BINARY_DIR}/${_target_name}.vcxproj.user") |
|---|
| 105 | ELSE() |
|---|
| 106 | STRING(REGEX REPLACE "^Visual Studio ([0-9][0-9]?).*$" "\\1" |
|---|
| 107 | VISUAL_STUDIO_VERSION_SIMPLE "${CMAKE_GENERATOR}") |
|---|
| 108 | CONFIGURE_FILE("${CMAKE_SOURCE_DIR}/src/template.vcproj.user.in" "${CMAKE_CURRENT_BINARY_DIR}/${_target_name}.vcproj.user") |
|---|
| 109 | ENDIF() |
|---|
| 110 | ENDIF(MSVC) |
|---|
| 111 | ENDMACRO(ORXONOX_ADD_EXECUTABLE) |
|---|
| 112 | |
|---|
| 113 | |
|---|
| 114 | MACRO(TU_ADD_TARGET _target_name _target_type _additional_switches) |
|---|
| 115 | CAPITALISE_NAME(${_target_name} _target_name_capitalised) |
|---|
| 116 | STRING(TOUPPER "${_target_name}" _target_name_upper) |
|---|
| 117 | |
|---|
| 118 | # Specify all possible options (either switch or with add. arguments) |
|---|
| 119 | SET(_switches FIND_HEADER_FILES EXCLUDE_FROM_ALL ORXONOX_EXTERNAL |
|---|
| 120 | NO_DLL_INTERFACE NO_SOURCE_GROUPS PCH_NO_DEFAULT |
|---|
| 121 | NO_INSTALL NO_VERSION NO_BUILD_UNITS |
|---|
| 122 | ${_additional_switches}) |
|---|
| 123 | SET(_list_names LINK_LIBRARIES VERSION SOURCE_FILES |
|---|
| 124 | DEFINE_SYMBOL TOLUA_FILES PCH_FILE |
|---|
| 125 | PCH_EXCLUDE OUTPUT_NAME LINK_LIBS_LINUX |
|---|
| 126 | LINK_LIBS_WIN32 LINK_LIBS_APPLE LINK_LIBS_UNIX |
|---|
| 127 | EXCLUDE_FROM_BUILD_UNITS) |
|---|
| 128 | |
|---|
| 129 | PARSE_MACRO_ARGUMENTS("${_switches}" "${_list_names}" ${ARGN}) |
|---|
| 130 | |
|---|
| 131 | # Process source files with support for build units |
|---|
| 132 | # Note: All file paths are relative to the root source directory, even the |
|---|
| 133 | # name of the build unit. |
|---|
| 134 | SET(_${_target_name}_source_files) |
|---|
| 135 | SET(_get_build_unit_file FALSE) |
|---|
| 136 | SET(_add_to_build_unit FALSE) |
|---|
| 137 | FOREACH(_file ${_arg_SOURCE_FILES}) |
|---|
| 138 | IF(_file STREQUAL "BUILD_UNIT") |
|---|
| 139 | # Next file is the name of the build unit |
|---|
| 140 | SET(_get_build_unit_file TRUE) |
|---|
| 141 | ELSEIF(_file STREQUAL "END_BUILD_UNIT") |
|---|
| 142 | IF(NOT _build_unit_file) |
|---|
| 143 | MESSAGE(FATAL_ERROR "No name provided for build unit") |
|---|
| 144 | ENDIF() |
|---|
| 145 | IF(ENABLE_BUILD_UNITS) |
|---|
| 146 | IF(NOT _build_unit_include_string) |
|---|
| 147 | MESSAGE(STATUS "Warning: Empty build unit!") |
|---|
| 148 | ENDIF() |
|---|
| 149 | IF(EXISTS ${_build_unit_file}) |
|---|
| 150 | FILE(READ ${_build_unit_file} _include_string_file) |
|---|
| 151 | ENDIF() |
|---|
| 152 | IF(NOT _build_unit_include_string STREQUAL "${_include_string_file}") |
|---|
| 153 | FILE(WRITE ${_build_unit_file} "${_build_unit_include_string}") |
|---|
| 154 | ENDIF() |
|---|
| 155 | LIST(APPEND _${_target_name}_source_files ${_build_unit_file}) |
|---|
| 156 | LIST(APPEND _${_target_name}_build_units ${_build_unit_file}) |
|---|
| 157 | # Store the number of files included. May be used for full build units. |
|---|
| 158 | SET_SOURCE_FILES_PROPERTIES(${_build_unit_file} |
|---|
| 159 | PROPERTIES BUILD_UNIT_SIZE "${_build_unit_count}") |
|---|
| 160 | ENDIF() |
|---|
| 161 | SET(_add_to_build_unit FALSE) |
|---|
| 162 | ELSEIF(_get_build_unit_file) |
|---|
| 163 | # Note: ${_file} is relative to the binary directory |
|---|
| 164 | SET(_build_unit_file ${CMAKE_BINARY_DIR}/${_file}) |
|---|
| 165 | SET(_get_build_unit_file FALSE) |
|---|
| 166 | SET(_add_to_build_unit TRUE) |
|---|
| 167 | SET(_build_unit_include_string) |
|---|
| 168 | SET(_build_unit_count "0") |
|---|
| 169 | ELSE() |
|---|
| 170 | # Default, add source file |
|---|
| 171 | |
|---|
| 172 | # Prepare relative paths |
|---|
| 173 | IF(NOT _file MATCHES "^(.\\:|\\/)") |
|---|
| 174 | # Path can be relative to the current source directory if the file was |
|---|
| 175 | # not added with the source file macros. Otherwise there is a "./" at |
|---|
| 176 | # the beginning of each file and the filename is relative |
|---|
| 177 | # to the CMAKE_SOURCE_DIR |
|---|
| 178 | STRING(REGEX REPLACE "^\\.\\/(.+)$" "\\1" _temp ${_file}) |
|---|
| 179 | IF(NOT ${_temp} STREQUAL ${_file}) |
|---|
| 180 | SET(_file ${CMAKE_SOURCE_DIR}/${_temp}) |
|---|
| 181 | ELSE() |
|---|
| 182 | SET(_file ${CMAKE_CURRENT_SOURCE_DIR}/${_file}) |
|---|
| 183 | ENDIF() |
|---|
| 184 | ENDIF() |
|---|
| 185 | |
|---|
| 186 | LIST(APPEND _${_target_name}_source_files ${_file}) |
|---|
| 187 | |
|---|
| 188 | # Handle build units |
|---|
| 189 | IF(_add_to_build_unit AND ENABLE_BUILD_UNITS) |
|---|
| 190 | IF(_file MATCHES "\\.(c|cc|cpp|cxx)$") |
|---|
| 191 | SET(_build_unit_include_string "${_build_unit_include_string}#include \"${_file}\"\n") |
|---|
| 192 | MATH(EXPR _build_unit_count "1 + ${_build_unit_count}") |
|---|
| 193 | ENDIF() |
|---|
| 194 | # Don't compile these files, even if they are source files |
|---|
| 195 | SET_SOURCE_FILES_PROPERTIES(${_file} PROPERTIES HEADER_FILE_ONLY TRUE) |
|---|
| 196 | ENDIF() |
|---|
| 197 | ENDIF() |
|---|
| 198 | ENDFOREACH(_file) |
|---|
| 199 | |
|---|
| 200 | # Assemble all header files of the library |
|---|
| 201 | IF(_arg_FIND_HEADER_FILES) |
|---|
| 202 | GET_ALL_HEADER_FILES(_${_target_name}_header_files) |
|---|
| 203 | ENDIF() |
|---|
| 204 | |
|---|
| 205 | # Combine source and header files |
|---|
| 206 | SET(_${_target_name}_files |
|---|
| 207 | ${_${_target_name}_header_files} |
|---|
| 208 | ${_${_target_name}_source_files} |
|---|
| 209 | ) |
|---|
| 210 | # Remove potential duplicates |
|---|
| 211 | LIST(REMOVE_DUPLICATES _${_target_name}_files) |
|---|
| 212 | |
|---|
| 213 | # TOLUA_FILES |
|---|
| 214 | IF(_arg_TOLUA_FILES) |
|---|
| 215 | GENERATE_TOLUA_BINDINGS(${_target_name_capitalised} _${_target_name}_files |
|---|
| 216 | INPUTFILES ${_arg_TOLUA_FILES}) |
|---|
| 217 | # Workaround for XCode: The folder where the bind files are written to has |
|---|
| 218 | # to be present beforehand. |
|---|
| 219 | IF(CMAKE_CONFIGURATION_TYPES) |
|---|
| 220 | FOREACH(_dir ${CMAKE_CONFIGURATION_TYPES}) |
|---|
| 221 | FILE(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${_dir}) |
|---|
| 222 | ENDFOREACH(_dir) |
|---|
| 223 | ENDIF() |
|---|
| 224 | ENDIF() |
|---|
| 225 | |
|---|
| 226 | # Mark files to be excluded from build units |
|---|
| 227 | IF(_arg_EXCLUDE_FROM_BUILD_UNITS) |
|---|
| 228 | SET_SOURCE_FILES_PROPERTIES(${_arg_EXCLUDE_FROM_BUILD_UNITS} |
|---|
| 229 | PROPERTIES EXCLUDE_FROM_BUILD_UNITS TRUE) |
|---|
| 230 | ENDIF() |
|---|
| 231 | |
|---|
| 232 | # Full build units |
|---|
| 233 | IF(ENABLE_BUILD_UNITS AND NOT _arg_NO_BUILD_UNITS) |
|---|
| 234 | # Use full build units even in partial mode for externals |
|---|
| 235 | IF(ENABLE_BUILD_UNITS MATCHES "full" OR _arg_ORXONOX_EXTERNAL) |
|---|
| 236 | GENERATE_BUILD_UNITS(${_target_name} _${_target_name}_files) |
|---|
| 237 | ENDIF() |
|---|
| 238 | ENDIF() |
|---|
| 239 | |
|---|
| 240 | # First part (pre target) of precompiled header files |
|---|
| 241 | IF(PCH_COMPILER_SUPPORT AND _arg_PCH_FILE) |
|---|
| 242 | # Provide convenient option to control PCH |
|---|
| 243 | IF(_arg_PCH_NO_DEFAULT) |
|---|
| 244 | SET(PCH_DEFAULT FALSE) |
|---|
| 245 | ELSE() |
|---|
| 246 | SET(PCH_DEFAULT TRUE) |
|---|
| 247 | ENDIF() |
|---|
| 248 | CMAKE_DEPENDENT_OPTION(PCH_ENABLE_${_target_name_upper} |
|---|
| 249 | "Enable using precompiled header files for library ${_target_name}." ${PCH_DEFAULT} PCH_ENABLE OFF) |
|---|
| 250 | # Almost never used individually, but produces a lot of options --> hide |
|---|
| 251 | MARK_AS_ADVANCED(PCH_ENABLE_${_target_name_upper}) |
|---|
| 252 | |
|---|
| 253 | IF(PCH_ENABLE_${_target_name_upper} AND NOT PCH_DISABLE_${_target_name}) |
|---|
| 254 | PRECOMPILED_HEADER_FILES_PRE_TARGET(${_target_name} ${_arg_PCH_FILE} _${_target_name}_files EXCLUDE ${_arg_PCH_EXCLUDE}) |
|---|
| 255 | ENDIF() |
|---|
| 256 | ENDIF() |
|---|
| 257 | |
|---|
| 258 | # Generate the source groups |
|---|
| 259 | IF(MSVC AND NOT _arg_NO_SOURCE_GROUPS) |
|---|
| 260 | GENERATE_SOURCE_GROUPS(${_${_target_name}_files}) |
|---|
| 261 | |
|---|
| 262 | IF(NOT _arg_ORXONOX_EXTERNAL) |
|---|
| 263 | # Move the ...Prereqs.h and the PCH files to the 'Config' section |
|---|
| 264 | IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${_target_name_capitalised}Prereqs.h) |
|---|
| 265 | SOURCE_GROUP("Config" FILES ${_target_name_capitalised}Prereqs.h) |
|---|
| 266 | ENDIF() |
|---|
| 267 | IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${_arg_PCH_FILE}) |
|---|
| 268 | SOURCE_GROUP("Config" FILES ${CMAKE_CURRENT_SOURCE_DIR}/${_arg_PCH_FILE}) |
|---|
| 269 | ENDIF() |
|---|
| 270 | ENDIF() |
|---|
| 271 | ENDIF() |
|---|
| 272 | |
|---|
| 273 | # Set link mode (SHARED/STATIC) |
|---|
| 274 | IF(MSVC AND _arg_NO_DLL_INTERFACE) |
|---|
| 275 | # Certain libraries don't have dllexport/dllimport and can't be linked shared with MSVC |
|---|
| 276 | SET(_link_mode STATIC) |
|---|
| 277 | ELSEIF(_arg_ORXONOX_EXTERNAL) |
|---|
| 278 | # Externals can be linked shared or statically |
|---|
| 279 | SET(_link_mode ${ORXONOX_EXTERNAL_LINK_MODE}) |
|---|
| 280 | ELSE() |
|---|
| 281 | # All our own libraries are linked dynamically because of static symbols |
|---|
| 282 | SET(_link_mode SHARED) |
|---|
| 283 | ENDIF() |
|---|
| 284 | |
|---|
| 285 | # No warnings needed from third party libraries |
|---|
| 286 | IF(_arg_ORXONOX_EXTERNAL) |
|---|
| 287 | REMOVE_COMPILER_FLAGS("-W3 -W4" MSVC) |
|---|
| 288 | ADD_COMPILER_FLAGS("-w" NOT MSVC) |
|---|
| 289 | ADD_COMPILER_FLAGS("-W0" MSVC) |
|---|
| 290 | ENDIF() |
|---|
| 291 | |
|---|
| 292 | # Don't compile header files |
|---|
| 293 | FOREACH(_file ${_${_target_name}_files}) |
|---|
| 294 | IF(NOT _file MATCHES "\\.(c|cc|cpp|cxx|mm|rc)$") |
|---|
| 295 | SET_SOURCE_FILES_PROPERTIES(${_file} PROPERTIES HEADER_FILE_ONLY TRUE) |
|---|
| 296 | ENDIF() |
|---|
| 297 | ENDFOREACH(_file) |
|---|
| 298 | |
|---|
| 299 | |
|---|
| 300 | |
|---|
| 301 | # Add the library/executable |
|---|
| 302 | IF("${_target_type}" STREQUAL "LIBRARY") |
|---|
| 303 | ADD_LIBRARY(${_target_name} ${_link_mode} |
|---|
| 304 | ${_arg_EXCLUDE_FROM_ALL} ${_${_target_name}_files}) |
|---|
| 305 | ELSE() |
|---|
| 306 | ADD_EXECUTABLE(${_target_name} ${_arg_WIN32} ${_arg_EXCLUDE_FROM_ALL} |
|---|
| 307 | ${_${_target_name}_files}) |
|---|
| 308 | ENDIF() |
|---|
| 309 | |
|---|
| 310 | |
|---|
| 311 | |
|---|
| 312 | # Change library prefix to "lib" |
|---|
| 313 | IF(MSVC AND ${_target_type} STREQUAL "LIBRARY") |
|---|
| 314 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES |
|---|
| 315 | PREFIX "lib" |
|---|
| 316 | ) |
|---|
| 317 | ENDIF() |
|---|
| 318 | |
|---|
| 319 | # MSVC hack to exclude external library sources from the intellisense database |
|---|
| 320 | # (IntelliSense stops working when adding "-Zm1000" as compile flag. "/Zm1000" |
|---|
| 321 | # would not work because of the slash) |
|---|
| 322 | IF(_arg_ORXONOX_EXTERNAL AND MSVC) |
|---|
| 323 | GET_TARGET_PROPERTY(_compile_flags ${_target_name} COMPILE_FLAGS) |
|---|
| 324 | IF(NOT _compile_flags) |
|---|
| 325 | SET(_compile_flags) |
|---|
| 326 | ENDIF() |
|---|
| 327 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES COMPILE_FLAGS "${_compile_flags} -Zm1000") |
|---|
| 328 | ENDIF() |
|---|
| 329 | |
|---|
| 330 | # Configure modules |
|---|
| 331 | IF (_arg_MODULE) |
|---|
| 332 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES |
|---|
| 333 | RUNTIME_OUTPUT_DIRECTORY ${CMAKE_MODULE_OUTPUT_DIRECTORY} # Windows |
|---|
| 334 | LIBRARY_OUTPUT_DIRECTORY ${CMAKE_MODULE_OUTPUT_DIRECTORY} # Unix |
|---|
| 335 | ) |
|---|
| 336 | ADD_MODULE_OR_PLUGIN(${_target_name} ${CMAKE_MODULE_OUTPUT_DIRECTORY} ${MODULE_INSTALL_DIRECTORY} ${ORXONOX_MODULE_EXTENSION}) |
|---|
| 337 | # Ensure that the main program depends on the module |
|---|
| 338 | SET(ORXONOX_MODULES ${ORXONOX_MODULES} ${_target_name} CACHE INTERNAL "") |
|---|
| 339 | ENDIF() |
|---|
| 340 | |
|---|
| 341 | # Configure plugins |
|---|
| 342 | IF (_arg_PLUGIN) |
|---|
| 343 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES |
|---|
| 344 | RUNTIME_OUTPUT_DIRECTORY ${CMAKE_PLUGIN_OUTPUT_DIRECTORY} # Windows |
|---|
| 345 | LIBRARY_OUTPUT_DIRECTORY ${CMAKE_PLUGIN_OUTPUT_DIRECTORY} # Unix |
|---|
| 346 | ) |
|---|
| 347 | ADD_MODULE_OR_PLUGIN(${_target_name} ${CMAKE_PLUGIN_OUTPUT_DIRECTORY} ${PLUGIN_INSTALL_DIRECTORY} ${ORXONOX_PLUGIN_EXTENSION}) |
|---|
| 348 | # Ensure that the main program depends on the plugin |
|---|
| 349 | SET(ORXONOX_MODULES ${ORXONOX_MODULES} ${_target_name} CACHE INTERNAL "") |
|---|
| 350 | ENDIF() |
|---|
| 351 | |
|---|
| 352 | # Static library flags are not globally available |
|---|
| 353 | IF(ORXONOX_STATIC_LINKER_FLAGS) |
|---|
| 354 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES STATIC_LIBRARY_FLAGS ${ORXONOX_STATIC_LINKER_FLAGS}) |
|---|
| 355 | ENDIF() |
|---|
| 356 | |
|---|
| 357 | # LINK_LIBRARIES |
|---|
| 358 | IF(_arg_LINK_LIBRARIES) |
|---|
| 359 | TARGET_LINK_LIBRARIES(${_target_name} ${_arg_LINK_LIBRARIES}) |
|---|
| 360 | ENDIF() |
|---|
| 361 | IF(_arg_LINK_LIBS_LINUX AND LINUX) |
|---|
| 362 | TARGET_LINK_LIBRARIES(${_target_name} ${_arg_LINK_LIBS_LINUX}) |
|---|
| 363 | ENDIF() |
|---|
| 364 | IF(_arg_LINK_LIBS_WIN32 AND WIN32) |
|---|
| 365 | TARGET_LINK_LIBRARIES(${_target_name} ${_arg_LINK_LIBS_WIN32}) |
|---|
| 366 | ENDIF() |
|---|
| 367 | IF(_arg_LINK_LIBS_APPLE AND APPLE) |
|---|
| 368 | TARGET_LINK_LIBRARIES(${_target_name} ${_arg_LINK_LIBS_APPLE}) |
|---|
| 369 | ENDIF() |
|---|
| 370 | IF(_arg_LINK_LIBS_UNIX AND UNIX) |
|---|
| 371 | TARGET_LINK_LIBRARIES(${_target_name} ${_arg_LINK_LIBS_UNIX}) |
|---|
| 372 | ENDIF() |
|---|
| 373 | |
|---|
| 374 | # Enable gcov (gcc code coverage analysis tool) if ENABLE_GCOV flag is defined |
|---|
| 375 | IF(ENABLE_GCOV) |
|---|
| 376 | TARGET_LINK_LIBRARIES(${_target_name} gcov) |
|---|
| 377 | ADD_COMPILER_FLAGS("-fprofile-arcs") |
|---|
| 378 | ADD_COMPILER_FLAGS("-ftest-coverage") |
|---|
| 379 | ENDIF() |
|---|
| 380 | |
|---|
| 381 | # Visual Leak Detector specific stuff (avoids the include) |
|---|
| 382 | IF(VISUAL_LEAK_DETECTOR_ENABLE) |
|---|
| 383 | TARGET_LINK_LIBRARIES(${_target_name} debug ${VLD_LIBRARY}) |
|---|
| 384 | ENDIF() |
|---|
| 385 | |
|---|
| 386 | # RPATH settings for the installation |
|---|
| 387 | IF("${_target_type}" STREQUAL "LIBRARY") |
|---|
| 388 | IF(_arg_MODULE) |
|---|
| 389 | SET(_rpath "${MODULE_RPATH}") |
|---|
| 390 | ELSEIF(_arg_PLUGIN) |
|---|
| 391 | SET(_rpath "${PLUGIN_RPATH}") |
|---|
| 392 | ELSE() |
|---|
| 393 | SET(_rpath "${LIBRARY_RPATH}") |
|---|
| 394 | ENDIF() |
|---|
| 395 | ELSE() |
|---|
| 396 | SET(_rpath "${RUNTIME_RPATH}") |
|---|
| 397 | ENDIF() |
|---|
| 398 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES INSTALL_RPATH "${_rpath}") |
|---|
| 399 | |
|---|
| 400 | # DEFINE_SYMBOL |
|---|
| 401 | IF(_arg_DEFINE_SYMBOL) |
|---|
| 402 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES DEFINE_SYMBOL ${_arg_DEFINE_SYMBOL}) |
|---|
| 403 | ELSEIF(NOT _arg_ORXONOX_EXTERNAL) |
|---|
| 404 | # Automatically add the macro definitions for our own libraries |
|---|
| 405 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES DEFINE_SYMBOL "${_target_name_upper}_SHARED_BUILD") |
|---|
| 406 | ENDIF() |
|---|
| 407 | |
|---|
| 408 | # VERSION |
|---|
| 409 | IF(_arg_VERSION) |
|---|
| 410 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES VERSION ${_arg_VERSION}) |
|---|
| 411 | ELSEIF(NOT _arg_ORXONOX_EXTERNAL AND NOT _arg_NO_VERSION AND NOT ${_target_type} STREQUAL "EXECUTABLE") |
|---|
| 412 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES VERSION ${ORXONOX_VERSION}) |
|---|
| 413 | ENDIF() |
|---|
| 414 | |
|---|
| 415 | # OUTPUT_NAME |
|---|
| 416 | IF(_arg_OUTPUT_NAME) |
|---|
| 417 | SET_TARGET_PROPERTIES(${_target_name} PROPERTIES OUTPUT_NAME ${_arg_OUTPUT_NAME}) |
|---|
| 418 | ENDIF() |
|---|
| 419 | |
|---|
| 420 | # Second part of precompiled header files |
|---|
| 421 | IF(PCH_COMPILER_SUPPORT AND PCH_ENABLE_${_target_name_upper} AND _arg_PCH_FILE AND NOT PCH_DISABLE_${_target_name}) |
|---|
| 422 | PRECOMPILED_HEADER_FILES_POST_TARGET(${_target_name} ${_arg_PCH_FILE}) |
|---|
| 423 | ENDIF() |
|---|
| 424 | |
|---|
| 425 | # Install all targets except for static ones (executables also have SHARED in _link_mode) |
|---|
| 426 | IF(${_link_mode} STREQUAL "SHARED" AND NOT _arg_NO_INSTALL) |
|---|
| 427 | IF(_arg_MODULE) |
|---|
| 428 | INSTALL(TARGETS ${_target_name} |
|---|
| 429 | RUNTIME DESTINATION ${MODULE_INSTALL_DIRECTORY} |
|---|
| 430 | LIBRARY DESTINATION ${MODULE_INSTALL_DIRECTORY} |
|---|
| 431 | ) |
|---|
| 432 | ELSEIF(_arg_PLUGIN) |
|---|
| 433 | INSTALL(TARGETS ${_target_name} |
|---|
| 434 | RUNTIME DESTINATION ${PLUGIN_INSTALL_DIRECTORY} |
|---|
| 435 | LIBRARY DESTINATION ${PLUGIN_INSTALL_DIRECTORY} |
|---|
| 436 | ) |
|---|
| 437 | ELSE() |
|---|
| 438 | INSTALL(TARGETS ${_target_name} |
|---|
| 439 | RUNTIME DESTINATION ${RUNTIME_INSTALL_DIRECTORY} |
|---|
| 440 | LIBRARY DESTINATION ${LIBRARY_INSTALL_DIRECTORY} |
|---|
| 441 | ) |
|---|
| 442 | ENDIF() |
|---|
| 443 | IF(INSTALL_PDB_FILES) # MSVC specific: install debug symbols files |
|---|
| 444 | FOREACH(_config RelForDevs RelWithDebInfo) |
|---|
| 445 | GET_TARGET_PROPERTY(_location ${_target_name} LOCATION_${_config}) |
|---|
| 446 | # Get absolute location without dll/exe extension |
|---|
| 447 | STRING(REGEX REPLACE "^(.+)\\.(dll|exe)$" "\\1" _location_we ${_location}) |
|---|
| 448 | IF(_arg_MODULE) |
|---|
| 449 | INSTALL(FILES ${_location_we}.pdb |
|---|
| 450 | DESTINATION ${MODULE_INSTALL_DIRECTORY} |
|---|
| 451 | CONFIGURATIONS ${_config} |
|---|
| 452 | ) |
|---|
| 453 | ELSEIF(_arg_PLUGIN) |
|---|
| 454 | INSTALL(FILES ${_location_we}.pdb |
|---|
| 455 | DESTINATION ${PLUGIN_INSTALL_DIRECTORY} |
|---|
| 456 | CONFIGURATIONS ${_config} |
|---|
| 457 | ) |
|---|
| 458 | ELSE() |
|---|
| 459 | INSTALL(FILES ${_location_we}.pdb |
|---|
| 460 | DESTINATION ${RUNTIME_INSTALL_DIRECTORY} |
|---|
| 461 | CONFIGURATIONS ${_config} |
|---|
| 462 | ) |
|---|
| 463 | ENDIF() |
|---|
| 464 | ENDFOREACH(_config) |
|---|
| 465 | ENDIF() |
|---|
| 466 | ENDIF() |
|---|
| 467 | |
|---|
| 468 | ENDMACRO(TU_ADD_TARGET) |
|---|
| 469 | |
|---|
| 470 | |
|---|
| 471 | # Creates a helper file with name <name_of_the_library>.<extension> |
|---|
| 472 | # This helps finding dynamically loadable modules or plugins at runtime |
|---|
| 473 | |
|---|
| 474 | FUNCTION(ADD_MODULE_OR_PLUGIN _target_name _output_dir _install_dir _extension) |
|---|
| 475 | # We use the properties to get the name because the librarys name may differ from |
|---|
| 476 | # the target name (for example orxonox <-> liborxonox) |
|---|
| 477 | IF (POLICY CMP0026) |
|---|
| 478 | CMAKE_POLICY(PUSH) |
|---|
| 479 | CMAKE_POLICY(SET CMP0026 OLD) # we only use the file's name, not its actual location, so the old policy is fine |
|---|
| 480 | ENDIF() |
|---|
| 481 | GET_TARGET_PROPERTY(_target_loc ${_target_name} LOCATION) |
|---|
| 482 | GET_FILENAME_COMPONENT(_target_filename ${_target_loc} NAME_WE) |
|---|
| 483 | IF (POLICY CMP0026) |
|---|
| 484 | CMAKE_POLICY(POP) # set policy back to original settings |
|---|
| 485 | ENDIF() |
|---|
| 486 | |
|---|
| 487 | IF(CMAKE_CONFIGURATION_TYPES) |
|---|
| 488 | FOREACH(_config ${CMAKE_CONFIGURATION_TYPES}) |
|---|
| 489 | SET(_helper_filename ${_output_dir}/${_config}/${_target_filename}${_extension}) |
|---|
| 490 | |
|---|
| 491 | FILE(WRITE ${_helper_filename} ${_target_name}) |
|---|
| 492 | |
|---|
| 493 | INSTALL( |
|---|
| 494 | FILES ${_helper_filename} |
|---|
| 495 | DESTINATION ${_install_dir} |
|---|
| 496 | CONFIGURATIONS ${_config} |
|---|
| 497 | ) |
|---|
| 498 | ENDFOREACH() |
|---|
| 499 | ELSE() |
|---|
| 500 | SET(_helper_filename ${_output_dir}/${_target_filename}${_extension}) |
|---|
| 501 | |
|---|
| 502 | FILE(WRITE ${_helper_filename} ${_target_name}) |
|---|
| 503 | |
|---|
| 504 | INSTALL( |
|---|
| 505 | FILES ${_helper_filename} |
|---|
| 506 | DESTINATION ${_install_dir} |
|---|
| 507 | ) |
|---|
| 508 | ENDIF() |
|---|
| 509 | ENDFUNCTION(ADD_MODULE_OR_PLUGIN) |
|---|
