source: orxonox.OLD/branches/avi_play/configure.ac @ 6028

##########################################################################
#   orxonox - the future of 3D-vertical-scrollers                        #
#                                                                        #
#   Copyright (C) 2004 orx                                               #
#                                                                        #
#   This program is free software; you can redistribute it and/or modify #
#   it under the terms of the GNU General Public License as published by #
#   the Free Software Foundation; either version 2, or (at your option)  #
#   any later version.                                                   #
#                                                                        #
#   ### File Specific:                                                   #
#   main-programmer: Benjamin Grauer                                     #
#   co-programmer: ...                                                   #
#                                                                        #
#   This is the main configuration File of autoconf.                     #
#   Please edit this file only, if you exactly know what you are doing.  #
#   It is quite fragile, and compiling orxonox on different Platforms    #
#   is only guarantied, if build with the right config.                  #
#                                                                        #
#   be sure to visit us at http://www.orxonox.net                        #
##########################################################################

#########################
## AUTOCONF INIT PHASE ##
#########################
AC_PREREQ(2.59)
AC_INIT([orxonox], [0.3.2_alpha], [orxonox-dev at mail.datacore.ch])

## Detect the canonical host and target build environment.
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

AM_INIT_AUTOMAKE

AC_CONFIG_SRCDIR([./src])
AC_CONFIG_HEADER([config.h])

#########################
## Checks for programs ##
#########################
AC_PROG_CXX
AC_PROG_RANLIB
AC_HEADER_STDC

## THIS IS OUR DEFAULT-DATA-DIRECTORY

##################################
## CHECKING  OPTIONAL ARGUMENTS ##
##################################
#----------------#
# Data-Directory #
#----------------#
DATA_DIR=$datadir
echo \$\{prefix\}
if test $DATA_DIR = \$\{prefix\}/share ; then
        echo "not given"
        DATA_DIR=/usr/share
else
        echo "given: $DATA_DIR"
fi
AC_DEFINE_UNQUOTED([DATADIR], ["$DATA_DIR"],
                   [Define to the read-only architecture-independent
                    data directory.])

#-----------------#
# shared-lib-path #
#-----------------#
SHARED_LIB_PATH=no
AC_MSG_CHECKING([shared lib path])
AC_ARG_WITH([shared-lib-path],
        AS_HELP_STRING(--with-shared-lib-path,Tells the executable, where to look for the shared libraries.),
         SHARED_LIB_PATH=$withval)
if test x$SHARED_LIB_PATH != xno; then
        echo "set to $SHARED_LIB_PATH"
else
        echo "no"
fi


#-----------------#
# DEBUG-statement #
#-----------------#
DEBUG=no
AC_MSG_CHECKING([if DEBUG-mode should be enabled])
AC_ARG_ENABLE([debug],
        AS_HELP_STRING(--enable-debug,compiles in debug mode. Lots of debug info about the game.),
         DEBUG=$enableval)

if test x$DEBUG = xno; then
        echo "no"
        echo " -> Setting debuglevel to 4. (orxonox is still in Development. It really is needed."
        DEBUG=4
elif test x$DEBUG = xyes; then
        echo "yes"
        echo " -> Setting debuglevel to 4. HARD DEBUG MODE!!."
        DEBUG=4
else
        echo "yes: setting debuglevel to to $DEBUG"
fi
AC_DEFINE_UNQUOTED(DEBUG, $DEBUG, [in which debug mode we are])
AC_SUBST(DEBUG)

#---------------#
# Modular Debug #
#---------------#
MODULAR_DEBUG=yes
AC_MSG_CHECKING([if Modular-DEBUG-mode should be ebabled])
AC_ARG_ENABLE([modular-debug],
        AS_HELP_STRING(--disable-modular-debug,compiles in modular-debug mode, that logs differently on the many modules of orxonox.),
         MODULAR_DEBUG=$enableval)

if test x$MODULAR_DEBUG = xno; then
        echo "no"
elif test x$MODULAR_DEBUG = xyes; then
        echo "yes"
        AC_DEFINE_UNQUOTED(MODULAR_DEBUG, 1, [if Modular-DUBUG mode is enabled])
fi

#--------------#
# GTK-disabled #
#--------------#
AC_MSG_CHECKING([if gtk should be enabled])
AC_ARG_ENABLE([gtk],
        AS_HELP_STRING(--disable-gtk,Prevents GTK from being loaded), [def_gtk=no], [def_gtk=yes])
if test x$def_gtk = xyes; then
  echo "yes"
fi
if test x$def_gtk = xno; then
  echo "no"
fi

#------------------#
# libCurl-disabled #
#------------------#
AC_MSG_CHECKING([if libcURL should be enabled])
AC_ARG_ENABLE([curl],
        AS_HELP_STRING(--disable-curl,Prevents libcURL from being loaded), [def_curl=no], [def_curl=yes])
if test x$def_curl = xyes; then
  echo "yes"
fi
if test x$def_curl = xno; then
  echo "no"
fi

#-------------------#
# SubProject-enable #
#-------------------#
def_sub_projects=no
AC_MSG_CHECKING([if the SubProjects should be built])
AC_ARG_WITH([sub-projects],
        AS_HELP_STRING(--with-sub-projects,also builds the subProjects while make from srcdir), [def_sub_projects=yes])
if test x$def_sub_projects = xyes; then
  echo "yes"
fi
if test x$def_sub_projects = xno; then
  echo "no"
fi
AM_CONDITIONAL(SUB_PROJECTS, test x$def_sub_projects = xyes)

#-------------------#
# Profiling Enabled #
#-------------------#
def_profiling=no
AC_MSG_CHECKING([if Profiling should be enabled])
AC_ARG_ENABLE([profile],
        AS_HELP_STRING(--enable-profile,builds orxonox with profiling support), [def_profiling=yes])
if test x$def_profiling = xyes; then
  echo "yes"
  CXXFLAGS="$CXXFLAGS -pg"
fi
if test x$def_profiling = xno; then
  echo "no"
fi

#----------------#
# efence Enabled #
#----------------#
def_efence=no
AC_MSG_CHECKING([if efence should be enabled])
AC_ARG_ENABLE([efence],
        AS_HELP_STRING(--enable-efence,builds orxonox with efence support), [def_efence=yes])
if test x$def_efence = xyes; then
  echo "yes"
fi
if test x$def_efence = xno; then
  echo "no"
fi

#----------------------#
# Documentation-enable #
#----------------------#
def_documentation=no
AC_MSG_CHECKING([if the Documentation should be build by default])
AC_ARG_ENABLE([documentation],
        AS_HELP_STRING(--enable-documentation,also builds the sDocumentation while make from srcdir), [def_documentation=yes])
if test x$def_documentation = xyes; then
  echo "yes"
fi
if test x$def_documentation = xno; then
  echo "no"
fi
AM_CONDITIONAL(DOCUMENTATION, test x$def_documentation = xyes)



#---------------------------#
# WITH TARDIS (convenience) #
#---------------------------#
def_tardis=no
GTKPATH=""
AC_MSG_CHECKING([convenience flag for working at the taris in the ETH zurich])
AC_ARG_WITH([tardis],
        AS_HELP_STRING(--with-tardis,sets all the necesary environment flags for linux-TARDIS boxes at the ETH Zurich), [def_tardis=yes])
if test x$def_tardis = xyes; then
  ARCH=i686-debian-linux3.1
   ## GAMELIBS
  PREFIX=/usr/pack/gamelibs-1.0-to
  CPPFLAGS="${CPPFLAGS} -I${PREFIX}/include"
  LDFLAGS="${LDFLAGS} -L$PREFIX/${ARCH}/lib -Wl,-rpath -Wl,${PREFIX}/${ARCH}/lib"
  ## GTK
  GTKPREFIX=/usr/pack/gtk-2.8.3-mo
  GTKPATH=${GTKPREFIX}/${ARCH}/bin
  CPPFLAGS="${CPPFLAGS} -I${GTKPREFIX}/include"
  LDFLAGS="${LDFLAGS} -L${GTKPREFIX}/${ARCH}/lib -Wl,-rpath -Wl,${GTKPREFIX}/${ARCH}/lib"
  echo "yes"
fi
if test x$def_tardis = xno; then
  echo "no"
fi

#######################
## PROGRAMM CHECKING ##
## 3. party Programs ##
#######################

#----------------------#
# checking for Doxygen #
#----------------------#
AC_PATH_PROG(DOXYGEN, doxygen)
AM_CONDITIONAL(DOXYGEN, test $DOXYGEN)

#--------------------#
# checking for gprof #
#--------------------#
AC_PATH_PROG(GPROF, gprof)

#-------------------------#
# checking for pkg-config #
#-------------------------#
if test x$def_gtk = xyes; then
 if test x${GTKPATH} != x; then
   AC_PATH_PROG([PKG_CONFIG], [pkg-config],[], $GTKPATH )
 else
   AC_PATH_PROG(PKG_CONFIG, pkg-config )
 fi
fi


#########################
## CHECKING FOR SYSTEM ##
#########################
## here the system is checked, and openGL is included
## also checking for SDL on differen Systems

AC_MSG_CHECKING([for System])
## checking for openGL-environment and other sys-specific parameters
case "$target" in

###########
#---------#
# WINDOWS #
#---------#
###########
  *-*-mingw32*)
echo "mingw-WINDOWS detected"

CPPFLAGS="-I/usr/include -I/mingw/include $CPPFLAGS"

    mingw="yes"
    MSBITFIELDS="-mms-bitfields"
    MWINDOWS="-mwindows"

#--------#
# MIN-GW #
#--------#
# checking for mingw32
    AC_CHECK_LIB([mingw32], [main], FOUND_mingw32=yes)
    if test x$FOUND_mingw32 = xyes; then
        LIBS="$LIBS -lmingw32"
    fi

#---------------#
# open-GL (win) #
#---------------#
# checking gl header
   AC_CHECK_HEADERS(GL/gl.h ,,
      [AC_MSG_ERROR([cannot find opengl headers])])
#   checking for Windows openGl library
    AC_CHECK_LIB([opengl32], [main], [FOUND_GL=yes; LIBS="$LIBS -lopengl32"])
    if test x$FOUND_GL != xyes ; then
         echo "------------------"
         echo "opengl not found."
         echo "please install the opengl package which can be found at http://www.opengl.org"
         echo "------------------"
         exit -1
    fi

# cheking for GLU-header
    AC_CHECK_HEADERS([GL/glu.h] ,,
      [AC_MSG_ERROR([cannot find opengl headers]) ])

# checking for libGLU
    AC_CHECK_LIB([glu32], [main], [FOUND_GLU=yes; LIBS="$LIBS -lGLU32"])
    if test x$FOUND_GLU != xyes ; then
         echo "------------------"
         echo "GLU library not found."
         echo "please install the GLU library, that should come with openGL, which can be found at http://www.opengl.org"
         echo "------------------"
         exit -1
    fi

# checking glew header
   AC_CHECK_HEADERS(GL/glew.h ,,
      [AC_MSG_ERROR([cannot find opengl extension wrangler headers]) ])
#   checking for Windows glew library
    AC_CHECK_LIB([glew32], [main], [FOUND_GLEW=yes; LIBS="$LIBS -lglew32"])
    if test x$FOUND_GLEW != xyes ; then
         echo "------------------"
         echo "opengl extension wrangler not found."
         echo "please install the glew package which can be found at http://glew.sourceforge.net"
         echo "------------------"
         exit -1
    fi

#--------#
# openAL #
#--------#
# checking for openAL-headers
  AC_CHECK_HEADERS([AL/al.h] ,,
      [AC_MSG_ERROR([cannot find openAL header.])])
# checking for openAL-lib
  AC_CHECK_LIB([OpenAL32], [main], [FOUND_OPENAL=yes; LIBS="$LIBS -lOpenAL32"])
  AC_CHECK_LIB([ALut], [main], [FOUND_ALUT=yes; LIBS="-lALut $LIBS"])
     if test x$FOUND_OPENAL != xyes ; then
        echo "------------------"
        echo "openal library not found."
        echo "please install the openal library, which can be found at http://www.openal.org"
        echo "------------------"
        exit -1
     fi


#-----------#
# SDL(win) #
#-----------#
# checking for SDL-headers
    AC_CHECK_HEADERS([SDL/SDL.h] ,,
      [AC_MSG_ERROR([cannot find SDL headers]) ])

#checking for libSDL
    AC_CHECK_LIB([sdlmain], [main], [FOUND_sdlmain=yes; LIBS="$LIBS -lsdlmain"])
    if test x$FOUND_sdlmain != xyes ; then
        echo "------------------"
        echo "SDL library not found."
        echo "please install the SDL library, which can be found at http://www.libsdl.org"
        echo "------------------"
        exit 1
    fi
    AC_CHECK_LIB([sdl], [main], [FOUND_SDL=yes; LIBS="$LIBS -lsdl"])
    if test x$FOUND_SDL != xyes ; then
        echo "------------------"
        echo "SDL library not found."
        echo "please install the SDL library, which can be found at http://www.libsdl.org"
        echo "------------------"
        exit -1
    fi

  ;;

#########
#-------#
# LINUX #
#-------#
#########
 *-*-linux*)
echo "Linux detected"

 Linux="yes"

##CPPFLAGS="-I/usr/include $CPPFLAGS"
##LDFLAGS="-L/usr/lib $LDFLAGS"
if test x$SHARED_LIB_PATH != xno; then
        echo "setting new LDFLAGS with $SHARED_LIB_PATH"
        LDFLAGS="-Wl,-rpath,$SHARED_LIB_PATH -L$SHARED_LIB_PATH $LDFLAGS"
fi

#--------#
# openGL #
#--------#
# checking gl header
   AC_CHECK_HEADERS([GL/gl.h] ,,
      [AC_MSG_ERROR([cannot find opengl headers]) ])

#  checking for Unix GL
   AC_CHECK_LIB([GL], [main], [FOUND_GL=yes; LIBS="$LIBS -lGL"])
   if test x$FOUND_GL != xyes ; then
         echo "------------------"
         echo "opengl not found."
         echo "please install the opengl package which can be found at http://www.opengl.org"
         echo "------------------"
         exit -1
   fi

# cheking for GLU-header
    AC_CHECK_HEADERS([GL/glu.h] ,,
      [AC_MSG_ERROR([cannot find opengl headers]) ])
    AC_CHECK_LIB([GLU], [main], [FOUND_GLU=yes; LIBS="$LIBS -lGLU"])
    if test x$FOUND_GLU != xyes ; then
         echo "------------------"
         echo "GLU library not found."
         echo "please install the GLU library, that should come with openGL, which can be found at http://www.opengl.org"
         echo "------------------"
         exit -1
    fi

# checking for GLEW-headers
   AC_CHECK_HEADERS([GL/glew.h] ,,
      [AC_MSG_ERROR([cannot find glew headers]) ])
# checking for GLEW-lib
  AC_CHECK_LIB([GLEW], [main], [FOUND_GLEW=yes; LIBS="$LIBS -lGLEW"])
   if test x$FOUND_GLEW != xyes ; then
         echo "------------------"
         echo "glew not found."
         echo "please install the glew package which can be found at http://glew.sourceforge.net"
         echo "------------------"
         exit -1
   fi

#--------#
# openAL #
#--------#
# checking for openAL-headers
  AC_CHECK_HEADERS([AL/al.h] ,,
      [AC_MSG_ERROR([cannot find openAL header.])])
# checking for openAL-lib
  AC_CHECK_LIB([openal], [main], [FOUND_OPENAL=yes; LIBS="$LIBS -lopenal"])
     if test x$FOUND_OPENAL != xyes ; then
        echo "------------------"
        echo "openal library not found."
        echo "please install the openal library, which can be found at http://www.openal.org"
        echo "------------------"
        exit -1
     fi
# checking for alut
  AC_CHECK_HEADERS([AL/alut.h] ,,
      [AC_MSG_ERROR([cannot find openAL Utility Toolkit (alut) header.])])
  AC_CHECK_LIB([alut], [main], [FOUND_ALUT=yes; LIBS="-lalut $LIBS"])

#-----#
# SDL #
#-----#
# checking for SDL
  AC_MSG_CHECKING([for SDL-version])
  SDL_VERSION=`sdl-config --version`
  echo $SDL_VERSION

   CPPFLAGS="$CPPFLAGS `sdl-config --cflags`"
   AC_CHECK_HEADERS([SDL.h] ,,
      [AC_CHECK_HEADERS([SDL/SDL.h] ,,AC_MSG_ERROR([cannot find SDL header. please download from libsdl.org])]))
   LIBS="`sdl-config --libs` $LIBS"
   AC_CHECK_LIB([SDL], [main], [FOUND_SDL=yes])
    if test x$FOUND_SDL != xyes ; then
        echo "------------------"
        echo "SDL library not found."
        echo "please install the SDL library, which can be found at http://www.libsdl.org"
        echo "------------------"
        exit -1
     fi

    ;;

#############
#-----------#
# MAC -OS X #
#-----------#
#############
 *darwin*)
 echo "OS X detected"

 osX="yes"

 CPPFLAGS="-I/sw/include -I/sw/include $CPPFLAGS"
 LDFLAGS="$LDFLAGS -L/sw/lib"
# checking gl header
   AC_CHECK_HEADERS([OpenGL/gl.h] ,,
      [AC_MSG_ERROR([cannot find opengl headers]) ])
# cheking for GLU-header
    AC_CHECK_HEADERS([OpenGL/glu.h] ,,
      [AC_MSG_ERROR([cannot find opengl headers]) ])

   LIBS="$LIBS -framework OpenGL"



# checking for GLEW-headers
   AC_CHECK_HEADERS([GL/glew.h] ,,
      [AC_MSG_ERROR([cannot find glew headers]) ])
# checking for GLEW-lib
  AC_CHECK_LIB([GLEW], [main], [FOUND_GLEW=yes; LIBS="$LIBS -lGLEW"])
   if test x$FOUND_GLEW != xyes ; then
         echo "------------------"
         echo "glew not found."
         echo "please install the glew package which can be found at http://glew.sourceforge.net"
         echo "------------------"
         exit -1
   fi


   AC_CHECK_HEADERS([OpenAL/al.h] ,,
      [AC_MSG_ERROR([cannot find opengl headers]) ])
  HAVE_OPENAL=yes
  LIBS="$LIBS -framework OpenAL"


## SDL-check
       SDL_CFLAGS=`sdl-config --cflags`
       SDL_LIBS=`sdl-config --libs`
       CXXFLAGS="$CXXFLAGS $SDL_CFLAGS"
       LIBS="$LIBS $SDL_LIBS"
   AC_CHECK_HEADERS([SDL/SDL.h] ,,
      [AC_MSG_ERROR([cannot find SDL headers]) ])
   HAVE_SDL=yes
#   LIBS="$LIBS -framework SDL"

# checking for SDL-headers
#    AC_CHECK_HEADERS(SDL/SDL.h ,,
#      [AC_MSG_ERROR([cannot find SDL headers]) ])

## checking for SDL
#    SDL_VERSION=1.2.7
#    AM_PATH_SDL($SDL_VERSION,
#      :,
#      AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
#      )


    ;;

  *)
    ;;
esac

AC_SUBST(MSBITFIELDS)

###################################
## CHECKING FOR HEADERS AND LIBS ##
###################################

#---------#
# SDL_ttf #
#---------#
# checking for SDL_ttf-headers
  AC_CHECK_HEADERS([SDL_ttf.h] ,,
      [AC_CHECK_HEADERS([SDL/SDL_ttf.h] ,,AC_MSG_ERROR([cannot find SDL_ttf header.])]))
# checking for SDL_ttf-lib
  AC_CHECK_LIB([SDL_ttf], [TTF_OpenFont], [FOUND_SDL_ttf=yes; LIBS="$LIBS -lSDL_ttf"])
     if test x$FOUND_SDL_ttf != xyes ; then
        echo "------------------"
        echo "SDL_ttf library not found."
        echo "please install the SDL_ttf library, which can be found at http://www.libsdl.org/projects/SDL_ttf/"
        echo "------------------"
        exit -1
     fi

#-----------#
# SDL_Image #
#-----------#
# checking for SDL_image-headers
AC_CHECK_HEADERS([SDL_image.h] ,,
    [AC_CHECK_HEADERS([SDL/SDL_image.h],, AC_MSG_ERROR([SDL_image header not found.]))])
# checking for SDL_image-lib
AC_CHECK_LIB([SDL_image], [main], [FOUND_SDL_image=yes; LIBS="$LIBS -lSDL_image"])
   if test x$FOUND_SDL_image != xyes ; then
      echo "------------------"
      echo "SDL_image library not found."
      echo "please install the SDL_image library, which can be found at http://www.libsdl.org/projects/SDL_image/"
      echo "------------------"
      exit -1
   fi

#---------#
# SDL_Net #
#---------#
# checking for SDL_net-headers
AC_CHECK_HEADERS([SDL_net.h] ,,
    [AC_CHECK_HEADERS([SDL/SDL_net.h],, AC_MSG_ERROR([SDL_net header not found.]))])
# checking for SDL_net-lib
AC_CHECK_LIB([SDL_net], [main], [FOUND_SDL_net=yes; LIBS="$LIBS -lSDL_net"])
   if test x$FOUND_SDL_net != xyes ; then
      echo "------------------"
      echo "SDL_net library not found."
      echo "please install the SDL_net library, which can be found at http://www.libsdl.org/projects/SDL_net/"
      echo "------------------"
      exit -1
   fi


#-----#
# ogg #
#-----#
# checking for ogg-headers
  AC_CHECK_HEADERS([ogg/ogg.h] ,,
      [AC_MSG_ERROR([cannot find ogg header.])])
# checking for ogg-lib
  AC_CHECK_LIB([ogg], [main], [FOUND_ogg=yes; LIBS="$LIBS -logg"])
     if test x$FOUND_ogg != xyes ; then
        echo "------------------"
        echo "ogg library not found."
        echo "please install the ogg library, which can be found at http://www.xiph.org/ogg/vorbis/index.html"
        echo "------------------"
        exit -1
     fi

#--------#
# vorbis #
#--------#
# checking for vorbis-lib
  AC_CHECK_LIB([vorbis], [main], [FOUND_vorbis=yes; LIBS="$LIBS -lvorbis"])
     if test x$FOUND_vorbis != xyes ; then
        echo "------------------"
        echo "vorbis library not found."
        echo "please install the vorbis library, which can be found at http://www.xiph.org/ogg/vorbis/index.html"
        echo "------------------"
        exit -1
     fi

#------------#
# vorbisfile #
#------------#
# checking for vorbis-headers
  AC_CHECK_HEADERS([vorbis/vorbisfile.h] ,,
      [AC_MSG_ERROR([cannot find vorbisfile header.])])
# checking for vorbisfile-lib
  AC_CHECK_LIB([vorbisfile], [main], [FOUND_vorbisfile=yes; LIBS="$LIBS -lvorbisfile"])
     if test x$FOUND_vorbisfile != xyes ; then
        echo "------------------"
        echo "vorbisfile library not found."
        echo "please install the vorbisfile library, which can be found at http://www.xiph.org/ogg/vorbis/index.html"
        echo "------------------"
        exit -1
     fi


#--------#
# FFmpeg # 
#--------#
# checking for FFmpeg-headers
  AC_CHECK_HEADERS([avformat.h] ,,
      [AC_CHECK_HEADERS([ffmpeg/avformat.h] ,,AC_MSG_ERROR([cannot find FFmpeg header.])]))
# checking for ffmpeg-lib
  AC_CHECK_LIB([avformat], [main], [FOUND_avformat=yes; LIBS="$LIBS -lavformat"])
     if test x$FOUND_avformat != xyes ; then
        echo "------------------"
        echo "avformat library not found."
        echo "please install the FFmpeg library, which can be found at http://ffmpeg.sourceforge.net"
        echo "------------------"
        exit -1
     fi
  AC_CHECK_HEADERS([avcodec.h] ,,
      [AC_CHECK_HEADERS([ffmpeg/avcodec.h] ,,AC_MSG_ERROR([cannot find FFmpeg header.])]))
  AC_CHECK_LIB([avcodec], [main], [FOUND_avcodec=yes; LIBS="$LIBS -lavcodec"])
     if test x$FOUND_avcodec != xyes ; then
        echo "------------------"
        echo "avcodec library not found."
        echo "please install the FFmpeg library, which can be found at http://ffmpeg.sourceforge.net"
        echo "------------------"
        exit -1
     fi
  AC_CHECK_LIB([theora], [main], [FOUND_theora=yes; LIBS="$LIBS -ltheora"])

  AC_CHECK_LIB([raw1394], [main], [FOUND_raw1394=yes; LIBS="$LIBS -lraw1394"])



#---------#
# libcURL #
#---------#
if test x$def_curl = xyes; then
 AC_CHECK_HEADERS([curl/curl.h], [curlHeader=yes], [curlHeader=no])
 AC_CHECK_LIB([curl], [main], [FOUND_curl=yes])
 if test x$curlHeader = xyes & test x$FOUND_curl = xyes ; then
  have_curl=yes
  CURL_LIBS=`curl-config --libs`
  CURLCFLAGS=`curl-config --cflags`
  AC_DEFINE_UNQUOTED(HAVE_CURL, 1, [if we have CURL])
 else
  have_curl=no
 fi

fi
AC_SUBST(CURL_LIBS)
AC_SUBST(CURL_CFLAGS)
AM_CONDITIONAL(HAVE_CURL, test x$have_curl = xyes)

#--------#
# efence #
#--------#
if test x$def_efence = xyes ; then
  AC_CHECK_LIB([efence], [main], [FOUND_efence=yes; LIBS="$LIBS -lefence"])
   if test x$FOUND_efence != xyes ; then
     echo "efence was requested, but is not installed!! going on"
   fi

fi

#-----#
# GTK #
#-----#
if test x$def_gtk = xyes; then
#PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.0.3 gthread-2.0 >= 2.0.3, have_gtk2=yes, have_gtk2=no)
        AC_MSG_CHECKING([for gtk2.0])
        if `$PKG_CONFIG --exists gtk+-2.0`; then
                echo "yes"
                have_gtk2=yes
                GTK2_LIBS=`$PKG_CONFIG --libs gtk+-2.0`
                GTK2_CFLAGS=`$PKG_CONFIG --cflags gtk+-2.0`
                AC_DEFINE_UNQUOTED(HAVE_GTK2, 1, [if we have GTK2])
                if test $DEBUG -ge 3; then
                 echo "cflags: $GTK2_CFLAGS"
                 echo "libs: $GTK2_LIBS"
                fi
        else
                echo "no"
        fi

fi
AC_SUBST(GTK2_LIBS)
AC_SUBST(GTK2_CFLAGS)
AM_CONDITIONAL(HAVE_GTK2, test x$have_gtk2 = xyes)


# FIXME: Replace `main' with a function in `-lm':
 AC_CHECK_LIB([m], [main])


# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([stdlib.h string.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([bzero sqrt])

######################
## OUTPUT CONFIGURE ##
######################
AC_CONFIG_FILES([Makefile
                 src/Makefile
                 src/lib/Makefile
                 src/lib/graphics/Makefile
                 src/lib/graphics/importer/Makefile
                 src/lib/graphics/spatial_separation/Makefile
                 src/lib/sound/Makefile
                 src/lib/event/Makefile
                 src/lib/physics/Makefile
                 src/lib/particles/Makefile
                 src/lib/collision_detection/Makefile
                 src/lib/network/Makefile
                 src/lib/shell/Makefile
                 src/lib/gui/Makefile
                 src/lib/gui/gtk_gui/Makefile
                 src/lib/gui/gl_gui/Makefile
                 src/lib/parser/Makefile
                 src/lib/parser/tinyxml/Makefile
                 src/lib/parser/ini_parser/Makefile
                 src/util/Makefile
                 src/subprojects/Makefile
                 src/subprojects/testmain/Makefile
                 src/subprojects/importer/Makefile
                 src/subprojects/particles/Makefile
                 src/subprojects/collision_detection/Makefile
                 src/subprojects/network/Makefile
                 ])

AC_OUTPUT